1.1 Données ouvertes et liées du graphe Wikidata

Wikidata est une base de connaissances libre, éditée de manière collaborative et hébergée par la fondation Wikimedia. Son contenu étant placé sous licence CC0 (« Transfert dans le Domaine Public »), elle permet de centraliser l’accès aux données utilisées par différents projets Wikimedia (Wikipédia (2021)).

Les informations saisies dans Wikidata sont des données ouvertes “brutes” multilingues non supervisées qui sont liées, notamment, aux articles de l’encyclopédie contributive Wikipedia. Wikidata est à différencier de l’ontologie DBpedia¹ (figure 1) au sens où l’ontologie sous-jacente de Wikidata n’est pas formalisée a priori - ce qui est le cas de DBpedia -, mais elle émerge des usages et pratiques de la communauté Wikidata. En effet, les deux dispositifs à vocation encyclopédique diffèrent dans leurs finalités initiales. DBpedia est un effort de la communauté scientifique pour extraire des informations structurées du projet encyclopédique Wikipedia et les lier à d’autres formalismes de données du Web sémantique. Wikidata est un dispositif de curation² ou d’annotation de données par les contributeurs et contributrices de Wikipedia ou Wikidata.

La base Wikidata fournit un support à de nombreux autres sites et services au-delà des seuls projets de Wikimedia. Son contenu est exporté dans des formats standards et peut être lié ou aligné à d’autres ensembles de données ouvertes sur le Web des données³. Wikidata offre ainsi un large domaine d’informations générales sur notre univers ou ses représentations et des liens vers d’autres graphes ou bases de données. Il contient à ce jour plus de 100 millions d’items.
La dynamique de création collective de ce projet encyclopédique peut être saisie à l’oreille grâce à l’application développée par Stephen LaPorte et Mahmoud Hashemi.

1.2 Standard RDF du W3C

Le RDF (Resource Data Framework) est un cadre général de modélisation utilisé pour décrire formellement les ressources du Web⁴ via leurs métadonnées afin de permettre le traitement par inférence de telles descriptions. Développé par le W3C⁵, le RDF est le formalisme de base du Web sémantique.

Au sein de ce paradigme, un document ou une ressource consiste en un ensemble de triplets⁶, chacun associant un sujet, un prédicat et un objet :

• le “sujet” du prédicat représente la ressource à décrire,
  
• le “prédicat” représente un type de propriété applicable à cette ressource,
  
• l’“objet” représente une donnée, une autre ressource ou une valeur associée à la propriété (ou prédicat).

Le sujet et l’objet, dans le cas où ce sont des ressources, peuvent être identifiés par un identifiant unique de la ressource (URI⁷), une valeur ou être des nœuds anonymes. Le prédicat est nécessairement identifié par un identifiant unique de la ressource. Par exemple, la déclaration “Bob s’intéresse à Mona Lisa” est formalisée de la manière suivante :

Un dépôt de triplets RDF ainsi formé correspond à un multigraphe orienté étiqueté : chaque triplet correspond alors à une arête orientée dont l’étiquette est le prédicat, le sujet est le nœud source et l’objet est le nœud cible (figure 3).

1.3 Le langage SPARQL

SPARQL⁸ (prononcé sparkle, en français : « étincelle ») est à la fois un langage de requête et un protocole qui permettent de rechercher, d’ajouter, de modifier ou de supprimer des triplets RDF disponibles à travers le Web. Aujourd’hui, le Web de données (représenté par le nuage du Linked Open Data ou ses domaines) est interrogeable via des centaines de services SPARQL qui mettent à disposition de plus en plus de graphes de données ouvertes et liées comme c’est le cas du projet plurilingue Wikidata (Wikipédia (2022)).

Vocabulaire ou espace de noms

Dans Wikidata les entités et leurs coordonnées spatiales et temporelles sont modélisées selon les fragments de graphes lisibles par l’humain et la machine dans divers formats⁹ : XML, json, turtle, etc. Ces différents formats proposent une sérialisation différente d’un même modèle, le RDF. Ce sont des graphes de connaissances qui décrivent des entités et leurs relations. Pour Wikidata comme pour d’autres modèles de données, il existe un vocabulaire spécifique. En général, les ontologies du Web sémantique disposent d’un vocabulaire décrit au sein d’espaces de noms associés au micro-monde décrit.

Par exemple, pour modéliser les données des réseaux sociaux, il existe un vocabulaire dédié Friend of a friend (FOAF) ; pour les ressources bibliographiques, la BnF mobilise notamment le vocabulaire Functional Requirements for Bibliographic Records (FRBR) élaboré par la Fédération internationale des associations et institutions de bibliothèques (IFLA) etc. Un autre exemple est l’ontologie du domaine associée à la diffusion de la musique fondée en 2002 avec l’initiative MusicBrainz (Swartz 2002), “corne d’abondance des communs” musicaux, déployée avec l’émergence du Web.

L’espace de nom de l’ontologie de Wikipedia, DBpedia est accessible à cette URL : https://dbpedia.org/ontology/.

Préfixes et requêtes

À chaque vocabulaire utilisé pour construire la requête sont associés différents préfixes¹⁰. Dans le cas présenté, la déclaration du vocabulaire mobilisé (celui de Wikidata notamment) est intégrée aux packages utilisés. Toutefois, en général, il est nécessaire de le préciser dans l’en-tête de la requête SPARQL, sous une certaine forme :

PREFIX préfixe: <espace de nom>

Les éléments d’un triplet prennent alors la forme suivante :

prédicat = préfixe:propriété
domaine/co-domaine = préfixe:entité

Le préfixe identifie le cadre de définition de concept. Par exemple, l’entité “ville” peut être décrite par “la ville de l’urbaniste”, “la ville du géographe”, “la ville selon l’Insee”, etc. En effet, les ontologies et les vocabulaires sont généralement construits dans un cadre disciplinaire (histoire, épidémiologie, géographie, biologie, etc.) ou de domaine d’activité (bibliothèques, musées, archives, etc.). Il est donc possible de retrouver un même terme désignant une entité ou un concept, mais qui le définit différemment. Par exemple, supposons que les termes ou concepts d’un champ de l’urbanisme sont décrits dans l’espace numérique dans une page http://mondomaineurbanisme.fr/, et ceux d’un champ de la géographie dans une autre page http://mondomainegeographie.fr/ (toutes deux fictives ici). Les préfixes associés, respectivement PREFIX urba:<http://mondomaineurbanisme.fr/#> et PREFIX geo:<http://mondomainegeographie.fr/#> par exemple, permettent non seulement de simplifier la syntaxe : <http://mondomaineurbanisme.fr/#>:ville en urba:ville ou <http://mondomainegeographie.fr/#>:ville en geo:ville mais aussi de résoudre les questions de définition ou de polysémie d’un même terme (ici “ville”) dans deux domaines disciplinaires différents.

Classiquement, pour rechercher dans le vocabulaire DBpedia (dbo) des entités qui ont pour type ville dans le vocabulaire RDF (rdf), on peut écrire le triplet sous la forme suivante :

?city rdf:type dbo:city

sous réserve de déclarer en tête de la requête SPARQL les préfixes des vocabulaires DBpedia et RDF :

PREFIX dbo: <http://dbpedia.org/ontology/> 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> 

Puis, si on souhaite connaître leur pays de rattachement, dans le vocabulaire DBpedia, on peut écrire un second triplet :

?city dbo:country ?country

Au sein des deux triplets, le point d’interrogation ? permet de préciser, dans la requête, quelles sont les entités recherchées : des objets de type ville (dbo:city) dans la variable ?city et leur pays respectif (dbo:country) dans la variable ?country.

Avec la déclaration des espaces de noms et la simplification de la syntaxe utilisant des préfixes, il est possible d’interroger des graphes (bases de données dites NoSQL¹¹) au moyen d’un protocole SPARQL sur un point de présence (SPARQLEndPoint) au sein d’un réseau HTTP.

Dans la suite, plusieurs préfixes Wikidata spécifiques aux entités et aux types de propriétés sont utilisés. Dans le cadre de notre étude, le tableau suivant récapitule les classes et propriétés utilisées, ainsi que quelques préfixes du schéma Wikidata utilisés pour former les triplets :

Dans le cas où le prédicat de Wikidata est utilisé avec le préfixe p, ps ou pq, la donnée associée est une assertion (spécifiée dans la tableau par le suffixe -St), c’est-à-dire un autre triplet. Ces spécificités du graphe Wikidata sont abordées dans la partie 3.

2.1 Packages utilisés

Les packages utilisés pour réaliser l’ensemble de la chaîne de traitement présenté dans ce document sont les suivants :

• wikidataR¹² (et son extension WikidataQueryServiceR) : permet d’écrire une requête pour interroger le graphe de données Wikidata au moyen d’une interface de programmation d’application (API) pour le service de requêtes Wikidata en langage SPARQL¹³ ;
  
• rnaturalearth : met à disposition les données géographiques de Natural Earth ;
  
• sf : permet la gestion et la manipulation de données géographiques vectorielles ;
  
• dplyr : pour la manipulation des données ;
  
• mapview : pour l’affichage interactif de données géographiques (repose sur la librairie JavaScript Leaflet) ;
  
• tmap : pour la création de cartes thématiques ;
  
• ggplot2 : permet la production de graphiques basés sur la grammaire graphique (Wilkinson 2005) ;
  
• av : génère des vidéos à partir d’images ou de graphiques R ;
  
• patchwork : permet de combiner plusieurs graphiques ggplot2 dans la fenêtre graphique ;
  
• jpeg : permet l’import, l’enregistrement et l’affichage des images matricielles (format bitmap) ;

Vous pouvez utiliser les lignes de code suivantes pour installer ces packages :

# Liste des packages du CRAN nécessaires
liste_packages <- c("WikidataR",
                    "WikidataQueryServiceR",
                    "remotes",
                    "rnaturalearth",
                    "sf",
                    "dplyr",
                    "mapview",
                    "tmap",
                    "ggplot2",
                    "av",
                    "patchwork",
                    "jpeg")

# Packages à installer
liste_packages_a_installer <- liste_packages[!(liste_packages %in% installed.packages()[,"Package"])]

# Installation des packages manquants
install.packages(liste_packages_a_installer)

# Pour les versions les plus récentes de RStudio
# see https://stackoverflow.com/questions/78402917/compiling-error-for-packages-installation\
#-after-updating-to-r-4-4-on-ubuntu-22-0 et, le cas échéant, décommenter ci-dessous.
# install.packages("progress")

Les informations sur le système d”exploitation et les versions des packages utilisés pour générer ce notebook sont disponibleq en fin de document.

2.2 Données collectées

Plusieurs sources de données sont utilisées pour ce travail exploratoire :

1. des données issues du graphe Wikidata ;
   
2. une couche géographique Natural Earth ;
   
3. des fonds de carte accessibles via Leaflet.

Télécharger les données

3.3 Lister les œuvres du peintre et trouver leurs localisations géographiques

Dans cette seconde étape, on se propose de lister les œuvres de Johannes Vermeer avec leurs localisations. Au sein du graphe Wikidata, on fait l’hypothèse que les coordonnées de la localisation d’une œuvre, c’est-à-dire la valeur point(x,y), sont celles du musée ou de l’institution où l’œuvre est actuellement exposée ou située. Afin d’obtenir cette localisation à partir de l’identifiant du peintre, on trace un premier chemin du graphe tel qu’illustré dans la figure 6.

On utilise le terme SPARQL OPTIONAL pour permettre de collecter les données y compris dans le cas où l’information de localisation d’une œuvre n’existerait pas dans Wikidata.

Sélectionner les données œuvre, musée et coordonnées telles que {
    l'œuvre a pour peintre Johannes Vermeer;               # chemin principal
    en option {
                 l'œuvre est localisée dans un musee          # chemin optionnel
                 ce musée a pour localisation les coordonnées  # chemin optionnel
              }
}

SELECT ?oeuvre ?musee ?coord WHERE 
           { 
             ?oeuvre wdt:P170 wd:Q41264 . 
             OPTIONAL 
             {  
               ?oeuvre wdt:P276 ?musee . 
               ?musee wdt:P625 ?coord 
             } 
           }

 query <- "SELECT ?oeuvre ?musee ?coord WHERE \
           { \
             ?oeuvre wdt:P170 wd:Q41264 . \
             OPTIONAL \
             { \ 
               ?oeuvre wdt:P276 ?musee . 
               ?musee wdt:P625 ?coord \
             } \ 
           }"

## Exécution de la requête
data2_WR <- WikidataR::query_wikidata(query)

Sélectionner les noms des données oeuvre, musée et les coordonnées telles que { 
    l'œuvre a pour peintre Johannes Vermeer;                 # chemin principal
    en option {
                l'œuvre est localisée dans un musee           # chemin optionnel
                ce musée a pour localisation les coordonnées   # chemin optionnel
                }
    en langue anglaise (en)                                    # service Wikilabel
} 

SELECT ?oeuvreLabel ?museeLabel ?coord WHERE
                 {
                   ?oeuvre wdt:P170 wd:Q41264 .
                   OPTIONAL
                    {
                      ?oeuvre wdt:P276 ?musee . 
                      ?musee wdt:P625 ?coord
                    }
                   SERVICE wikibase:label
                    {
                      bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en".
                    }
                  }

query_label <- "SELECT ?oeuvreLabel ?museeLabel ?coord WHERE \
                 { \
                   ?oeuvre wdt:P170 wd:Q41264 . \
                   OPTIONAL \
                    { \ 
                      ?oeuvre wdt:P276 ?musee . 
                      ?musee wdt:P625 ?coord \
                    } \
                   SERVICE wikibase:label \
                    { \
                      bd:serviceParam wikibase:language \"[AUTO_LANGUAGE], en \". \
                    } \
                  }"

## Exécution de la requête
data2_WQSR <- query_wikidata(query_label)

3.4 Premiers éléments d’analyse exploratoire

Sélectionner les données œuvre et leur nom telles que { 
   l'œuvre a pour créateur le peintre Johannes Vermeer;  # chemin principal
   en langue anglaise   (en)                              # service Wikilabel
} 
par ordre décroissant       # ordonne        

SELECT ?oeuvre ?oeuvreLabel 
WHERE
     {
       ?oeuvre wdt:P170 wd:Q41264
       SERVICE wikibase:label
               {
                bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en ".
               }
      }
ORDER BY DESC(?oeuvre)

query_valeur_simple <- "SELECT  ?oeuvre ?oeuvreLabel WHERE \
                        { \
                          ?oeuvre wdt:P170 wd:Q41264 \ 
                            SERVICE wikibase:label \
                            { \
                              bd:serviceParam wikibase:language \"[AUTO_LANGUAGE], en \". \
                            } \
                        } \
                        ORDER BY DESC( ?oeuvre )"

## Exécution de la requête
resultats_oeuvres_valeur_simple <- WikidataQueryServiceR::query_wikidata(query_valeur_simple)

nrow(resultats_oeuvres_valeur_simple)

[1] 37

Sélectionner les données œuvre et leur nom telles que { 
   l'œuvre est liée à une assertion de création au peintre Johannes Vermeer; # chemin principal
   en langue anglaise   (en)                                                  # service Wikilabel
} 
par ordre décroissant       # ordonne     

SELECT ?oeuvre ?oeuvreLabel 
WHERE
     {
     ?oeuvre p:P170/ps:P170 wd:Q41264  
     SERVICE wikibase:label
             {
              bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en ".
             } 
     } 
ORDER BY DESC(?oeuvre)